home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Belgian Amiga Club - ADF Collection
/
BS1 part 26.zip
/
BS1 part 26
/
Powervisor v1.10b disk1.adf
/
s
/
pv
/
DispMemList
< prev
next >
Wrap
Text File
|
1990-11-26
|
2KB
|
89 lines
;Utility for PowerVisor to show the memorylist
;(c) J.Tyberghein 6 may 1990 V1.1
; 11 jun 1990 V1.2
;
; DispMemList <start>
p=0
onerror Einde
_pm=mode
mode hex
cls
getarg
_start=rc
_size=512*1024
_end=_start+_size
loadfd >nil graphics fd:graphics_lib.fd
locate 0,2
print 'Memory Map V1.2\0a'
print 'White is free\0a'
v SetAPen(rp(),1) Move(rp(),298,8) Draw(rp(),621,8) Draw(rp(),621,216)
v Draw(rp(),298,216) Draw(rp(),298,8)
s=0
p=alloc(n,10)
label Lus
v Move(rp(),292,10+(s*13)) Draw(rp(),298,10+(s*13))
d >*p _start+(s*(_size/16))
v Move(rp(),226,13+(s*13)) Text(rp(),p,8)
s=s+1
if s<16
goto Lus
endif
v free(p)
p=0
clear 041424344
search >nil _start _size 'ABCDABCD'
if !rc
print 'No free memory !\0a'
goto Einde
endif
_st=rc
label Loop
rc=_st+4
go "\20\11\02\80\ff\ff\ff\fe\20\40\0c\98\41\42\43\44\67\f8\22\88\4e\75"
_en=rc
if _en>=_end
_en=_end
endif
_x1=(((_st-_start)/8)%320)+300
_y1=(((_st-_start)/8)/320)+10
_x2=(((_en-_start)/8)%320)+300
_y2=(((_en-_start)/8)/320)+10
if _y1==_y2
v Move(rp(),_x1,_y1) Draw(rp(),_x2,_y1)
else
v Move(rp(),_x1,_y1) Draw(rp(),619,_y1) Move(rp(),300,_y2) Draw(rp(),_x2,_y2)
if _y2>(_y1+1)
v RectFill(rp(),300,_y1+1,619,_y2-1)
endif
endif
if _en==_end
goto Einde
endif
search >nil _en _end-_en 'ABCDABCD'
if rc
_st=rc
goto Loop
endif
label Einde
if p
v free(p)
p=0
endif
locate 0,28
mode=_pm
remvar _pm
remvar _en
remvar _end
remvar _start
remvar _st
remvar _size
remvar p
remvar _x1
remvar _x2
remvar _y1
remvar _y2
remvar s